Создание мультивыносок

[АлексейТ]

Прошу помогите кто ни будь!
Я пытаюсь создать лисп превращающий выбранный текст или мультитекст в
мультивыноску, но видать из за скудности моих познаний в данной тематике
не удаётся преодолеть ошибочку (пишет ошибка неверный список)!

Код - Auto/Visual Lisp [Выбрать]

1. Привожу текст искомого лиспа:
2. (defun c:vin (/ vin lst t1 t2 t3 t4)
3.   (setq t1 (ssget "_:S"))
4.   (setq t2 (ssname t1 0))
5.   (setq t3 (entget t2))
6. (setq t4 (nth 1 (assoc 1 t3)))
7.   (setq vin (getpoint))
8.   (VL-cmdf "_mleader" vin t4 "")
9. )

[Александр Ривилис]

Приветствую на форуме!
1. Создание одинаковых сообщений в разных ветках форума запрещено (п. 4.2. Правил).
2. Эта строка точно неверна. Проверь её:

Код - Auto/Visual Lisp [Выбрать]

1. (setq t4 (nth 1 (assoc 1 t3)))

[АлексейТ]

Александр если я не использую функцию nth то возвращается список (1 . "тект")-это если ещё убрать команду _mleader , а вместе с этой командой возвращается сообщение что "В команду послан неверный тип
nil".
Потому то я логично поразмыслив и решил что функцией nth изыму сам "текст", но увы не так не так не работает.
P.S.^По поводу задвоения тем приношу свои извенения стыдно признаться но я вообще впервые пользуюсь услугами форумов.

[Александр Ривилис]

Александр если я не использую функцию nth то возвращается список (1 . "тект")-это если ещё убрать команду _mleader , а вместе с этой командой возвращается сообщение что "В команду послан неверный тип
nil".

В этом случае нужно пользоваться функцией (cdr), а не (nth), так как у тебя не обычный список, а точечный.
Вообще же есть большая тема на dwg.ru о создании мультивыносок: http://forum.dwg.ru/showthread.php?t=27965

[АлексейТ]

Благодарю!
Непременно изучу!

[АлексейТ]

Ура!
Всё получилось!
Функция cdr помогла!

Код - Auto/Visual Lisp [Выбрать]

1. (defun c:vin (/ vin lst t1 t2 t3 t4 t5)
2.   (setq t1 (ssget "_:S"))
3.   (setq t2 (ssname t1 0))
4.   (setq t3 (entget t2))
5.   (setq t4 (cdr (assoc 1 t3)))
6.   (setq t5 (strcat t4))
7.   (setq vin (getpoint))
8.   (VL-cmdf "_mleader" vin pause t5 "")
9. )

[АлексейТ]

Немного усовершенствовал!
теперь лисп удаляет ранее выбраный текст

Код - Auto/Visual Lisp [Выбрать]

1. (defun c:vin (/ vin lst t1 t2 t3 t4 t5)
2.   (setq t1 (ssget "_:S"))
3.   (setq t2 (ssname t1 0))
4.   (setq t3 (entget t2))
5.   (setq t4 (cdr (assoc 1 t3)))
6.   (setq t5 (strcat t4))
7.   (setq vin (getpoint))
8.   (VL-cmdf "_mleader" vin pause t5 "")
9.   (entdel t2)
10. )

[Александр Ривилис]

В какой версии AutoCAD? Если внимательно прочитать статью Порядок создания мультивыноски (MLEADER) в AutoCAD, то видно что (начиная кажется с AutoCAD 2013) порядок запросов в команде может меняться.

[Александр Ривилис]

Есть еще один недостаток у этого метода (общий для всех версий AutoCAD). В группе 1 для MTEXT хранится до 255 символов, а остальные хранятся в цепочке групп 3.

[АлексейТ]

AutuCad 2015.

[Александр Ривилис]

AutoCAD 2015.

Значит в любой момент, если пользователь переключит режим, программа работать не будет.

[Алексей Кулик]

В первом приближении, без контроля результата (это надо уже отдельно делать)

Код - Auto/Visual Lisp [Выбрать]

1. (vl-load-com)
2.  
3. (defun c:vin (/ adoc selset pt ml _kpblc-objectidtoobject idx)
4.  
5.   (defun _kpblc-objectidtoobject (obj id)
6.     (if (and (> (vl-string-search "x64" (getvar "platform")) 0)
7.              (vlax-method-applicable-p obj 'objectidtoobject32)
8.              ) ;_ end of and
9.       (vla-objectidtoobject32 obj id)
10.       (vla-objectidtoobject obj id)
11.       ) ;_ end of if
12.     ) ;_ end of defun
13.  
14.   (if
15.     (and (= (type (setq selset (vl-catch-all-apply
16.                                  (function
17.                                    (lambda ()
18.                                      (ssget "_+.:L:S" '((0 . "*TEXT")))
19.                                      ) ;_ end of lambda
20.                                    ) ;_ end of function
21.                                  ) ;_ end of vl-catch-all-apply
22.                         ) ;_ end of setq
23.                   ) ;_ end of type
24.             'pickset
25.             ) ;_ end of =
26.          (setq selset (vlax-ename->vla-object (ssname selset 0)))
27.          (= (type
28.               (setq pt (vl-catch-all-apply
29.                          (function (lambda () (getpoint "\nТочка, от которой будет строиться мультивыноска <Отмена> : ")))
30.                          ) ;_ end of vl-catch-all-apply
31.                     ) ;_ end of setq
32.               ) ;_ end of type
33.             'list
34.             ) ;_ end of =
35.          pt
36.          ) ;_ end of and
37.      (progn
38.        (vla-startundomark (setq adoc (vla-get-activedocument (vlax-get-acad-object))))
39.        (setq
40.          ml (vla-addmleader (_kpblc-objectidtoobject adoc (vla-get-ownerid selset))
41.                             (vlax-make-variant
42.                               (vlax-safearray-fill
43.                                 (vlax-make-safearray vlax-vbdouble
44.                                                      '(0 . 5)
45.                                                      ) ;_ end of vlax-make-safearray
46.                                 (append pt (vlax-safearray->list (vlax-variant-value (vla-get-insertionpoint selset))))
47.                                 ) ;_ end of vlax-safearray-fill
48.                               ) ;_ end of vlax-make-variant
49.                             1
50.                             ) ;_ end of vla-addmleader
51.          ) ;_ end of setq
52.        (vla-put-contenttype ml 2)
53.        (vla-put-textstring ml (vla-get-textstring selset))
54.        (vla-erase selset)
55.        (vla-endundomark adoc)
56.        ) ;_ end of progn
57.      ) ;_ end of if
58.   (princ)
59.   ) ;_ end of defun

[АлексейТ]

Посоветуйте пожалуйста а как сделать лисп устанавливающий
скрытие заднего плана с заданным коэффициентом для всех
мультивыносок чертежа!

[Алексей Кулик]

Один вопрос = одна тема.